import com.myflashlab.air.extensions.ar.*;
      
     AR.init("Wikitude_Android_SDK_key", "Wikitude_iOS_SDK_key");
      
     AR.listener.addEventListener(ArEvents.WORLD_LOAD_RESULT, onWorldLoadResult);
     AR.listener.addEventListener(ArEvents.NATIVE_WINDOW_CLOSED, onArClosed);
     AR.listener.addEventListener(ArEvents.CALIBRATION_NEEDED, onCalibrationNeeded);
     AR.listener.addEventListener(ArEvents.CALIBRATION_DONE, onCalibrationDone);
     AR.listener.addEventListener(ArEvents.JS_TALK, onJsTalk);
     AR.listener.addEventListener(ArEvents.SCREENSHOT_RESULT, onScreenshotresult);
      
     var features:Array = [];
     features.push(Features.GEO);
     features.push(Features.IMAGE_TRACKING);
     features.push(Features.INSTANT_TRACKING);
     features.push(Features.OBJECT_TRACKING);
     AR.checkFeatureSupport(features, onCheckResult);
      
     function onCheckResult($status:int, $msg:String):void
     {
         if($status == AR.RESULT_OK)
         {
             trace("Device supports all requested AR features");
             // now, use the permissionCheck ANE to ask users for camera and gps permissions
             // https://github.com/myflashlab/PermissionCheck-ANE/
             whenPermissionsAreOk();
         }
         else if($status == AR.RESULT_ERROR)
         {
             trace("Device does not support all features: " + $msg);
         }
     }
      
     function whenPermissionsAreOk():void
     {
         var _arSettings:Config = new Config();
         _arSettings.camFocusMode = CameraFocusMode.CONTINUOUS;
         _arSettings.camPosition = CameraPosition.BACK;
         _arSettings.camResolution = CameraResolution.SD_640x480;
          
         // for best performance, you must activated only the AR features which you will use.
         _arSettings.hasGeo = true;
         _arSettings.hasInstant = true;
         _arSettings.hasIR = true;
         _arSettings.hasObject = true;
          
         if(AR.os == AR.ANDROID)
         {
             // Android specific settings
             _arSettings.android.cam2Enabled = false;
             _arSettings.android.fullscreenMode = true;
             _arSettings.android.camFocusDistanceAndroid = 1;
         }
         else if(AR.os == AR.IOS)
         {
             // iOS specific settings
             _arSettings.ios.camFocusDistance = -1.0;
             _arSettings.ios.camFocusRange = FocusRange.NONE;
             _arSettings.ios.framerate = 30;
             _arSettings.ios.excludeBinnedVideo = true;
         }
          
         AR.config(_arSettings);
         AR.launchAR("AR_world/index.html");
     }
      
     function onWorldLoadResult(e:ArEvents):void
     {
         if(e.status == AR.RESULT_OK)
         {
             trace("AR World load succeeded for URL: " + e.url);
         }
         else if(e.status == AR.RESULT_ERROR)
         {
             trace("AR World load failed for URL: " + e.url);
             trace("failed reason: " + e.msg);
         }
     }
      
     function onArClosed(e:ArEvents):void
     {
         trace("AR closed");
     }
      
     function onCalibrationNeeded(e:ArEvents):void
     {
         trace("onCalibrationNeeded");
     }
      
     function onCalibrationDone(e:ArEvents):void
     {
         trace("onCalibrationDone");
     }
      
     function onJsTalk(e:ArEvents):void
     {
         trace("onJsTalk: " + e.msg);
          
         // you may call functions on the js side using the AR.callJS method.
          AR.callJS("remoteJSfunction('value1', 'value2')");
          
         // The best practice is to send a json string from js to AIR
         var obj:Object = JSON.parse(e.msg);
          
         if(obj.action == "close_ar")
         {
             AR.endAR();
         }
         else if(obj.action == "capture_screen")
         {
             AR.captureScreen(
                 Screenshot.CAPTURE_MODE_CAM,
                 "screenshot.png" // relative path to File.applicationStorageDirectory
             );
         }
     }
      
     function onScreenshotresult(e:ArEvents):void
     {
         if(e.status == AR.RESULT_OK)
         {
             trace("screenshot success", e.screenshot.nativePath + " = " + e.screenshot.size);
         }
         else if(e.status == AR.RESULT_ERROR)
         {
             trace("screenshot failed reason: " + e.msg);
         }
     }